Como fazer o Visual Basic 6 esperar um programa terminar a execução?

Question

Eu queria fazer o seguinte:

Queria que o programa feito em VB6 esperasse o término da execução do programa. Ex:

retval=shell("wget.exe www.google.com.br")

Depois que terminar o download, mas somente depois que o programa terminasse a execução ele desse a mensagem

Msgbox "Download concluído",16,"Pronto!"

Como é que eu faço para que o VB entenda que eu quero que o programa espere pelo término da execução?

Answer 1

Olha, segundo o "HELP" do VB:

Por padrão, a função Shell executa outros programas assincronamente. Isso significa que um programa iniciado com Shell poderá não concluir a execução antes que as instruções seguintes à função Shell sejam executadas.

Mas, boas notícias: achei alguma coisa para o VB 4, não sei o quento a resposta pode ser usada - "Como determinar quando um processo 'Shelled' Terminou" e "Monitorar o status de um processo 'Shelled'":
(obs.: a tradução foi do tradutor automático da Microsoft)
Usando a função Windows API GetModuleUsage(), seu programa Visual Basic pode monitorar o status de um processo 'shelled'. O valor de retorno da função Shell() pode ser usado para chamar a função GetModuleUsage() continuamente em um um loop para descobrir se o programa shelled foi concluído. Se a função Shell() é bem-sucedido, o valor de retorno é o identificador-instância para o programa 'shelled'. Esse identificador-instância pode ser passado para a função GetModuleUsage() para determinar a contagem de referência para o módulo. Quando a função GetModuleUsage() retorna um valor de 0 ou menos, o programa 'shelled' foi concluído.

(São dois artigos com códigos diferentes, vou colocar aqui o primeiro)

Exemplo do Passo a passo
1.Iniciar Visual Basic para Windows ou do menu Arquivo, escolher New Project ALT, F, (N) se Visual Basic para Windows já execução. O Form1 é criado por padrão..
2.Adicione o seguinte codificar para a seção Declarações gerais de Form1:

Private Declare Function GetModuleUsage% Lib "Kernel" _
(ByVal hModule%)

Private Function TestFunc(ByVal lVal As Long) As Integer
'this function is necessary since the value returned by Shell is an
'unsigned integer and may exceed the limits of a VB integer
If (lVal And &H8000&) = 0 Then
TestFunc = lVal And &HFFFF&
Else
TestFunc = &H8000 Or (lVal And &H7FFF&)
End If
End Function


3.Codificar o procedimento de evento Form_Click de Form1 para adicionar o seguinte:

Sub Form_Click()
lRet& = Shell("NOTEPAD.EXE") ' Modify the path as necessary.
x% = TestFunc(lRet&)
While GetModuleUsage(x%) > 0 ' Has Shelled program finished?
z% = DoEvents() ' If not, yield to Windows.
Wend
MsgBox "Shelled application just terminated", 64
End Sub


4.A partir do menu Executar, escolher Iniciar ALT, R, (S) para executar o programa.
5.Usando o mouse, clique na janela Form1. Neste apontar, o aplicativo Bloco de Notas é shelled.

(aqui vai o código do segundo artigo, em inglês, parece que é para VB 6)

Step-by-Step Example
1.Start a new project in Visual Basic. Form1 is created by default.
2.Add the following code to the General Declarations section of Form1:

Private Type STARTUPINFO
cb As Long
lpReserved As String
lpDesktop As String
lpTitle As String
dwX As Long
dwY As Long
dwXSize As Long
dwYSize As Long
dwXCountChars As Long
dwYCountChars As Long
dwFillAttribute As Long
dwFlags As Long
wShowWindow As Integer
cbReserved2 As Integer
lpReserved2 As Long
hStdInput As Long
hStdOutput As Long
hStdError As Long
End Type

Private Type PROCESS_INFORMATION
hProcess As Long
hThread As Long
dwProcessID As Long
dwThreadID As Long
End Type

Private Declare Function WaitForSingleObject Lib "kernel32" (ByVal _
hHandle As Long, ByVal dwMilliseconds As Long) As Long

Private Declare Function CreateProcessA Lib "kernel32" (ByVal _
lpApplicationName As String, ByVal lpCommandLine As String, ByVal _
lpProcessAttributes As Long, ByVal lpThreadAttributes As Long, _
ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, _
ByVal lpEnvironment As Long, ByVal lpCurrentDirectory As String, _
lpStartupInfo As STARTUPINFO, lpProcessInformation As _
PROCESS_INFORMATION) As Long

Private Declare Function CloseHandle Lib "kernel32" _
(ByVal hObject As Long) As Long

Private Declare Function GetExitCodeProcess Lib "kernel32" _
(ByVal hProcess As Long, lpExitCode As Long) As Long

Private Const NORMAL_PRIORITY_CLASS = &H20&
Private Const INFINITE = -1&

Public Function ExecCmd(cmdline$)
Dim proc As PROCESS_INFORMATION
Dim start As STARTUPINFO

' Initialize the STARTUPINFO structure:
start.cb = Len(start)

' Start the shelled application:
ret& = CreateProcessA(vbNullString, cmdline$, 0&, 0&, 1&, _
NORMAL_PRIORITY_CLASS, 0&, vbNullString, start, proc)

' Wait for the shelled application to finish:
ret& = WaitForSingleObject(proc.hProcess, INFINITE)
Call GetExitCodeProcess(proc.hProcess, ret&)
Call CloseHandle(proc.hThread)
Call CloseHandle(proc.hProcess)
ExecCmd = ret&
End Function

Sub Form_Click()
Dim retval As Long
retval = ExecCmd("notepad.exe")
MsgBox "Process Finished, Exit Code " & retval
End Sub


3.Press the F5 key to run the application.
4.Using the mouse, click the Form1 window. At this point the NotePad application is started.
5.Quit NotePad. A MsgBox appears indicating termination of the NotePad application and an exit code of 0.

NOTE: The MsgBox statement following the ExecCmd() function is not executed because the WaitForSingleObject() function prevents it. The message box does not appear until Notepad is closed when the user chooses Exit from Notepad's File menu (ALT, F, X).

(Os links de onde tirei o código VB seguem na janela abaixo)