EXCEL中VLOOKUP如何比對兩個以上條件(急~15點)

Question

VLOOKUP疑難，請教高手來解答
如果我想要比對兩個以上的條件
函數應該如何設才好?

比方說
SHEET 1
Ａ１名稱　 Ｂ１尺寸 　 Ｃ１金額　
CDA(一點) 3/8"
　　
SHEET 2
Ａ１名稱　 Ｂ１尺寸 　 Ｃ１金額　
CDA(一點) 1/4" 61,040
CDA(一點) 3/8" 69,200
PN2/GN2/O2(一點) 1/4" 94,374


如果我希望利用SHEET1的A1與 B1兩個條件來比對SHEET2的A1、 B1、C1然後幫我代出SHEET1中的C1金額應該怎麼做呢?

請熟悉EXCEL的高手幫忙喔～

Answer 1

方法一：使用 VLOOKUP 的方法～

圖片參考：http://gtfi.myweb.hinet.net/1507021210408/01.gif


在 Sheet2 插入A 欄，當成輔助欄
A2 輸入公式 =B2&C2
回 Sheet1 工作表 C2 儲存格，輸入下列公式：
=VLOOKUP(A2&B2,Sheet2!$A$1:$D$4,4,0)
此公式可以往下複製
完成

方法二：不增加輔助欄的方法～

圖片參考：http://gtfi.myweb.hinet.net/1507021210408/02.gif


在 Sheet1 工作表 C2 輸入下列公式：
=LOOKUP(2,1/((Sheet2!$A$2:$A$4=A2)*(Sheet2!$B$2:$B$4=B2)),Sheet2!$C$2:$C$4)
此公式可以往下複製
完成

Answer 2

VLOOKUP 無法比對兩個以上的條件. 除非如大師所述加上補助欄之方法.
此說法是有問題的.
解決方法D欄須為空格欄
C2=--VLOOKUP(A2&B2,Sheet2!$A$2:$C$4&Sheet2!$B$2:$D$4,3,0)
陣列公式加按Ctrl＋Shift＋Enter
所得結果為文字格式故前面須加”－－”
提供參考

Answer 3

VLOOKUP 無法比對兩個以上的條件. 除非如大師所述加上補助欄之方法.

或者使用大師所述之 LOOKUP 之公式. (大師巧妙使用了此函數喔!)
再者, 可嘗試 SUMPRODUCT 之公式如下:
SHEET1, C2 = SUMPRODUCT((Sheet2!A$2:A$5=A2)*(Sheet2!B$2:B$5=B2),Sheet2!C$2:C$5)
再往下複製即可.

2007-02-23 00:11:17 補充：
Applerot,

Thanks so much. 又多瞭解 VLOOKUP 之一種用法.