excel好困擾

Question

excel運算函數要增加什麼函數，才能在無運算數值時，讓答案欄空白，而不是產生0？？
例：欄A 欄B 欄C 欄D
5 4 3 =SUM(A1:C1)
4 3 2 =SUM(A2:C2)
空白 空白 空白 =0 「←就是它，它可不可以公式仍然存在，但不要出現任何字呀><|||(在沒填入任何可運算的數值時)」

我的煩腦=IF(AND(D24>7,E24<31),210,IF(E24>30,E24*7,IF(E24/D24>4,E24*7,D24*30))) 這個函數，以下兩種方式都沒辦法用也，會顯示#VALUE!，請問有其他用法嗎？？

小芳：
=IF(AND(D5<10),D5*30,IF(D5=10,D5*30,IF(D5>10,(D5-10)*10 300)))
是否也可以套用你說的ISERROR呢？
如果可以的話，我的程式是否設定錯誤呢？？

Answer 1

=IF(AND(D24>7,E24<31),210,IF(E24>30,E24*7,IF(E24/D24>4,E24*7,D24*30))) 這個函數改為
=IF((COUNTIF(D24:E24,"")=0)*(D24<>0),IF(AND(D24>7,E24<31),210,IF(E24>30,E24*7,IF(E24/D24>4,E24*7,D24*30))),"")

如D24:E24不等於空字串""且D24不等於0則執行原公式
=IF(AND(D5<10),D5*30,IF(D5=10,D5*30,IF(D5>10,(D5-10)*10 300))) 改為
=IF(D5="","",IF(AND(D5<10),D5*30,IF(D5=10,D5*30,IF(D5>10,(D5-10)*10300))))
只D5為變數判斷D5就可以


2007-01-09 22:47:37 補充：
第一個問題可改為:
=IF(COUNTIF(A1:C1,"")<>3,SUM(A1:C1),"")

=IF(D5="","",IF(AND(D5<10),D5*30,IF(D5=10,D5*30,IF(D5>10,(D5-10)*10＋300))))
看中間有空格是不是少一個＋號

Answer 2

在你要輸入的函數外加上
=IF(X="","",............)

X 是你要輸入資料那列的第一欄
例如前三列是表頭跟標題列 資料是從第四列開始的 那X就是A4
............是你原先的計算公式

Answer 3

改成下式即可:
=IF(ISERROR(IF(AND(D24>7,E24<31),210,IF(E24>30,E24*7,IF(E24/D24>4,E24*7,D24*30)))),"",IF(AND(D24>7,E24<31),210,IF(E24>30,E24*7,IF(E24/D24>4,E24*7,D24*30))))

2007-01-09 20:27:29 補充：
使用 IF、ISERROR 和 NA 函數來執行這個工作:

選取包含錯誤值的儲存格。
於儲存格中輸入下列公式，其中 old_formula 為儲存格先前的公式。
=IF(ISERROR(old_formula),"",old_formula)

Answer 4

您的公式不須做任何變動
只要在D欄(整欄)儲存格格式設[自訂]-->#,###" "就可以了
將D欄整欄Mark-->上方功能表[格式]-->[儲存格]-->出現[儲存格格式]對話框
選[數值]-->下方[自訂]-->右邊[類型]下方欄位內輸入-->#,###" "


2007-01-10 07:27:51 補充：
不知小純版主有沒有試過小弟提供的方法
有沒有聽過職場的KISS理論:Keep It Simple & Stupid
小弟喜歡嘗試用最簡單的方法達到同樣的功能
不須要把問題複雜化

Answer 5

公式改為
=IF(SUM(A1:C1)=0,"",SUM(A1:C1))

或選取D欄,"格式/儲存格/數值/自訂",在右方"類型"中輸入：
0;-0;

Answer 6

EXCEL有個函數叫做 ISNUMBER，可以用來判斷是否為數字。
所以，以您的 SUM(a1:c1) 為例，您可以用
IF(OR(ISNUMBER(A1),ISNUMBER(B1),ISNUMBER(C1)),SUM(A1:C1),"")
即可滿足您的要求