excel如何跳列加總

Question

我想從a1+a7+a13+......a900 , 每次跳6格,有沒有比較快的方式,

不好意思補充一下

小明 1月份 2月份 3月份 4月份 5月份 6月份 小計
薪資
伙食
加班
扣繳

小美 1月份 2月份 3月份 4月份 5月份 6月份 小計
薪資
伙食
加班
扣繳
.......假設有100人
我想要把每人的薪資,伙食,加班,扣繳小計部分 做總計,要如何下公式

Answer 1

Sheet1!
　Ａ　　Ｂ　　Ｃ　　　Ｄ　　Ｅ　　Ｆ　　　Ｇ　　Ｈ
小明　1月份　2月份　3月份　4月份　5月份　6月份　小計
薪資
伙食
加班
扣繳

小美　1月份　2月份　3月份　4月份　5月份　6月份　小計
薪資
伙食
加班
扣繳
：
：
　Ｉ　　　Ｊ
１薪資　輸入公式
２伙食　
３加班
４扣繳
J1=SUMPRODUCT(($A$1:$A$900=I1)*ISNUMBER($H$1:$H$900),$H$1:$H$900)
將公式下拉填滿到J4
公式說明:
計算尋找 $A$1:$A$900=I1　；$A$1:$A$900="薪資"　的列位子
和$H$1:$H$900是數值的資料,因H1、H7"小計"為文字無法計算
兩條件成立($A$2=I1)*ISNUMBER($H$2)=1*1=1
再乘H2得到每人的薪資小計,將全部加總

各陣列必須有相同的維度 (相同的列數，相同的欄數)。否則 SUMPRODUCT 函數會傳回錯誤值 #VALUE!。
SUMPRODUCT 函數會將所有非數值資料的陣列元素當成 0 來處理。

2006-12-16 12:19:48 補充：
剛測試一下ISNUMBER函數可不用,將公式修改:
J1=SUMPRODUCT(--($A$1:$A$900=I4),$H$1:$H$900)
另一解法:
J1=SUMPRODUCT(($A$2:$A$900=I1)*($B$1:$H$1="小計"),$B$2:$H$900)
尋找附和薪資和小計的加總
如修改$B$1:$H$1="小計"的"小計"為"6月份"則計算6月份的薪資加總

2006-12-17 18:00:30 補充：
貼錯了I4改I1或直接輸入"薪資"
J1=SUMPRODUCT(--($A$1:$A$900=I1),$H$1:$H$900)
J1=SUMPRODUCT(--($A$1:$A$900=I1),$H$1:$H$900)

Answer 2

在任一儲存格輸入公式
=SUMPRODUCT(A1:A900,--(MOD(ROW(A1:A900),6)=1))
完成.


2006-12-14 18:01:34 補充：
有關 SUMPRODUCT() 的用法說明, 請參考網頁
http://tw.myblog.yahoo.com/whitefox-blog/article?mid=102&prev=120&next=100

2006-12-14 18:50:06 補充：
公式相同, 但參數需作調整.
假設薪資位置在 B2,B8,B14...., 則公式為
=SUMPRODUCT(B$2:B$900,--(MOD(ROW(B$2:B$900),6)=2))
假設伙食位置在 B3,B9,B15...., 則公式為
=SUMPRODUCT(B$2:B$900,--(MOD(ROW(B$2:B$900),6)=3))
餘此類推, 公式可往右複製到其他月份.

Answer 3

b1輸入公式
=IF(MOD(ROW(),6)=0,A1,"")
向下拖曳
於儲存格a901做加總
=sum(b1:b900)